* torque.sas, torque optimization experiment, Table 7.13 (page 228);
options ls=72;
;
DATA TORQUE;
  INPUT A B M Y;
  TC = (3*(A-1)) + B;
  LINES;
   1    1    1    16
   1    1    1    21
   1    2    1    38
   1    2    1    40
   1    3    1    48
   1    3    1    60
   2    1    1     8
   2    1    1    10
   2    2    1    22
   2    2    1    28
   2    3    1    28
   2    3    1    34
   3    1    1     8
   3    1    1    14
   3    2    1    18
   3    2    1    24
   3    3    1    20
   3    3    1    14
   1    1    2    24
   1    1    2    18
   1    2    2    36
   1    2    2    38
   1    3    2    42
   1    3    2    40
   2    1    2    16
   2    1    2    12
   2    2    2    16
   2    2    2    18
   2    3    2    16
   2    3    2    16
   3    1    2     8
   3    1    2     6
   3    2    2     8
   3    2    2    14
   3    3    2    16
   3    3    2    14
;
*  calculate the average data values for each ABM combination;
PROC SORT;     BY A B M;
PROC MEANS  NOPRINT MEAN VAR;
  VAR Y;     BY A B M ;
  OUTPUT OUT=TORQUE2 MEAN=AV_Y VAR=VAR_Y;
DATA TORQUE2;     SET TORQUE2;
  TC = (3*(A-1)) + B;
PROC PRINT;
  VAR A B TC M AV_Y VAR_Y;
PROC PLOT;
  PLOT AV_Y*M=TC AV_Y*M=B/VPOS=19 HPOS=50;
;
*  fit model for mixed array analysis with three factors;
DATA TORQUE;     SET TORQUE;
PROC GLM;
  CLASSES A B M;
  MODEL Y = A B A*B M A*M B*M A*B*M;
;
*  calculate  average and log var of data for each AB combination;
PROC SORT;     BY A B ;
PROC MEANS NOPRINT MEAN VAR;
  VAR Y;     BY A B ;
  OUTPUT OUT=TORQUE3 MEAN=AV_Y VAR=VAR_Y;
DATA TORQUE3; SET TORQUE3;
  TC = (3*(A-1)) + B;
  LVY = LOG(VAR_Y);
PROC PRINT;
  VAR A B TC AV_Y VAR_Y LVY;
;
*  analysis as a product array with response AV_Y;
PROC GLM;
  CLASSES A B ;
  MODEL AV_Y = A B A*B  ;
PROC PLOT;
  PLOT AV_Y*A=B/VPOS=19 HPOS=50;
*  analysis as a product array with response log VAR_Y;
PROC GLM;
  CLASSES A B ;
  MODEL LVY = A B A*B;
PROC PLOT;
  PLOT LVY*A=B/VPOS=19 HPOS=50;