* reaction.sas, reaction time experiment, Table 6.13 (page 176);
* (also exercise 4 of chapter 4, but then n=18);
options ls=72;
;
DATA  DATA1;
  INPUT ORDER A B Y;
  *** code the treatment combinations 11, 12, ..., 23;
  TC = 10*A + (B/5); 
  LINES;
   1 2 15 0.256
   2 2 15 0.281
   3 1 10 0.167
   4 2 15 0.258
   5 1 10 0.182
   6 2 10 0.283
   7 2  5 0.257
   8 2 10 0.235
   9 1  5 0.204
  10 1  5 0.170
  11 2 10 0.260
  12 1 10 0.187
  13 1 15 0.202
  14 2  5 0.279
;
PROC PRINT;
PROC GLM;
  CLASSES A B;
  MODEL Y = A B A*B;
      * Use MEANS only if sample sizes are equal;
  MEANS A  B / TUKEY CLDIFF ALPHA=0.01;
      * If sample sizes are unequal, use LSMEANS;
  LSMEANS A B/PDIFF=ALL CL ADJUST=TUKEY ALPHA=0.01;
  CONTRAST '11-13-21+23'  A*B 1  0 -1 -1  0  1;
  CONTRAST 'B1-B2' B 1 -1  0;
  ESTIMATE 'B1-B2' B 1 -1  0;
  ESTIMATE 'B1-B3' B 1  0 -1;
  ESTIMATE 'B2-B3' B 0  1 -1;
PROC GLM;
  CLASSES TC;
  MODEL Y = TC;
  MEANS TC / TUKEY CLDIFF ALPHA=0.01;
  LSMEANS TC/PDIFF=CONTROL CL ADJUST=DUNNETT ALPHA=0.01;
  LSMEANS TC/PDIFF=CONTROLL CL ADJUST=DUNNETT ALPHA=0.01;
  LSMEANS TC/PDIFF=CONTROLU CL ADJUST=DUNNETT ALPHA=0.01;
  CONTRAST '11-13-21+23'  TC  1  0 -1  -1  0  1;
  CONTRAST 'B1-B2'        TC  1 -1  0   1 -1  0;