* react2.sas, reaction time experiment, Table 6.17 (page 181),
* and in text code (pages 181-182);
options ls=72;
;
DATA DATA1;
  INPUT ORDER A$ B$ Y;
  TC=trim(A)||trim(B);  *name the trt comb as  11, 12, . . . , 23;
  LINES;
   1     2    3    0.256
   2     2    3    0.281
   3     1    2    0.167
   4     2    3    0.258
   5     1    2    0.182
   6     2    2    0.283
   7     2    1    0.257
   8     2    2    0.235
   9     1    1    0.204
  10     1    1    0.170
  11     2    2    0.260
  12     1    2    0.187
  13     1    3    0.202
  14     2    1    0.279
;
PROC GLM;
  CLASSES TC;
  MODEL Y = TC;
  OUTPUT OUT=RESIDS PREDICTED=PDY RESIDUAL=Z;
;
PROC PLOT;
  PLOT Y*TC Z*TC / VPOS=19 HPOS=50;
;
* other SAS code of Section 6.8.2;
* residuals by level of A (page 181);
PROC PLOT;
  PLOT Z*A=B / VPOS=19 HPOS=50;
;
* interaction plot mentioned in text (page 181);
PROC SORT DATA=DATA1;
  BY A B;
PROC MEANS DATA=DATA1 NOPRINT MEAN VAR;
  VAR Y;
  BY A B;
  OUTPUT OUT=DATA2 MEAN=AV_Y VAR=VAR_Y;
PROC PRINT;
  VAR A B AV_Y VAR_Y;
PROC PLOT;
  PLOT AV_Y*A=B / VPOS=19 HPOS=50;
;
* residual variances by A (page 182);
PROC SORT DATA=RESIDS;
  BY A;
PROC MEANS DATA=RESIDS NOPRINT VAR;
  VAR Z;
  BY A;
  OUTPUT OUT=DATA2 VAR=VAR_Z;
PROC PRINT;
  VAR A  VAR_Z;